init. mostly copied from nixpkgs#kitty, plus bold_is_bright.patch from kittypatch

disable-test_ssh_bootstrap_with_different_launchers.patch

@@ -0,0 +1,13 @@
+diff --git a/kitty_tests/ssh.py b/kitty_tests/ssh.py
+index 1f424146..d3cc191b 100644
+--- a/kitty_tests/ssh.py
++++ b/kitty_tests/ssh.py
+@@ -166,7 +166,7 @@ def test_ssh_bootstrap_with_different_launchers(self):
+             for sh in self.all_possible_sh:
+                 if sh == 'sh' or 'python' in sh:
+                     q = shutil.which(launcher)
+-                    if q:
++                    if q and not 'zsh' in q:
+                         with self.subTest(sh=sh, launcher=q), tempfile.TemporaryDirectory() as tdir:
+                             self.check_bootstrap(sh, tdir, test_script='env; exit 0', SHELL_INTEGRATION_VALUE='', launcher=q)
+ 

fix-test_ssh_env_vars.patch

@@ -0,0 +1,13 @@
+diff --git a/kitty_tests/ssh.py b/kitty_tests/ssh.py
+index 7b3bdbeb..710aeceb 100644
+--- a/kitty_tests/ssh.py
++++ b/kitty_tests/ssh.py
+@@ -272,8 +272,6 @@ def check_bootstrap(self, sh, home_dir, login_shell='', SHELL_INTEGRATION_VALUE=
+ 
+             def check_untar_or_fail():
+                 q = pty.screen_contents()
+-                if 'bzip2' in q:
+-                    raise ValueError('Untarring failed with screen contents:\n' + q)
+                 return 'UNTAR_DONE' in q
+             pty.wait_till(check_untar_or_fail)
+             self.assertTrue(os.path.exists(os.path.join(home_dir, '.terminfo/kitty.terminfo')))

flake.lock

@@ -0,0 +1,27 @@
+{
+  "nodes": {
+    "nixpkgs": {
+      "locked": {
+        "lastModified": 1688438960,
+        "narHash": "sha256-aIFcxU2qtI/LupfwcwTbVbadrF1KZLw2tsxyyl7WYtU=",
+        "owner": "NixOS",
+        "repo": "nixpkgs",
+        "rev": "62fed675bc20ceac4471d844164ec146888f0c27",
+        "type": "github"
+      },
+      "original": {
+        "owner": "NixOS",
+        "ref": "nixos-23.05-small",
+        "repo": "nixpkgs",
+        "type": "github"
+      }
+    },
+    "root": {
+      "inputs": {
+        "nixpkgs": "nixpkgs"
+      }
+    }
+  },
+  "root": "root",
+  "version": 7
+}

flake.nix

@@ -0,0 +1,54 @@
+# vim: set noet sw=2 ts=2 sts=2:
+{
+  description = "kitty";
+	inputs = {
+		nixpkgs.url = github:NixOS/nixpkgs/nixos-23.05-small;
+	};
+	outputs = { self, nixpkgs }:
+		let
+      allSystems = [ "x86_64-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin" ];
+      forAllSystems = f: (nixpkgs.lib.genAttrs allSystems (system: f {
+        pkgs = import nixpkgs { inherit system; };
+      }));
+    in rec {
+			defaultPackage = forAllSystems ({pkgs}:
+				with pkgs;
+        callPackage ./kitty.nix { }
+      );
+			packages = forAllSystems ({pkgs}:
+				with pkgs;
+				{ default = callPackage ./kitty.nix { }; }
+      );
+			devShell = forAllSystems ({pkgs}:
+        with pkgs;
+        let
+          sw = callPackage ./kitty.nix { };
+					environment =
+						(lib.attrsets.filterAttrs (n: v: null != (builtins.match "^[A-Z_]+$" n)) sw)
+						// { RAILS_ENV = "development"; };
+					q = lib.strings.escapeShellArg;
+        in
+          mkShell {
+            name = "kitty-dev";
+						inputsFrom = [sw];
+						shellHook = ''
+							${lib.strings.concatStringsSep " " (builtins.attrValues (builtins.mapAttrs (n: v: "${n}=${q v}") environment))}
+							export ${lib.strings.concatStringsSep " " (builtins.attrValues (builtins.mapAttrs (n: v: q n) environment))}
+						'';
+          }
+          // environment
+      );
+
+			apps = forAllSystems ({pkgs}:
+				with pkgs;
+				let
+					kitty = callPackage ./kitty.nix { };
+				in {
+					server = {
+						type = "app";
+						program = "dev.sh";
+					};
+				}
+			);
+		};
+}

kitty.nix

@@ -0,0 +1,244 @@
+{ lib, stdenv, fetchFromGitHub, python3Packages, libunistring
+, harfbuzz, fontconfig, pkg-config, ncurses, imagemagick
+, libstartup_notification, libGL, libX11, libXrandr, libXinerama, libXcursor
+, libxkbcommon, libXi, libXext, wayland-protocols, wayland
+, lcms2
+, librsync
+, openssl
+, installShellFiles
+, dbus
+, Libsystem ? null
+, Cocoa ? null
+, Kernel ? null
+, UniformTypeIdentifiers ? null
+, UserNotifications ? null
+, libcanberra
+, libicns
+, libpng
+, python3
+, zlib
+, bashInteractive
+, zsh
+, fish
+, nixosTests
+, go
+, buildGoModule
+, nix-update-script
+}:
+
+with python3Packages;
+buildPythonApplication rec {
+  pname = "kitty-patch";
+  version = "0.28.1";
+  format = "other";
+
+  src = fetchFromGitHub {
+    owner = "kovidgoyal";
+    repo = "kitty";
+    rev = "refs/tags/v${version}";
+    hash = "sha256-pAo+bT10rdQOf9j3imKWCCMFGm8KntUeTQUrEE1wYZc=";
+  };
+  vendorHash = "sha256-vq19exqsEtXhN20mgC5GCpYGm8s9AC6nlfCfG1lUiI8=";
+
+  buildInputs = [
+    harfbuzz
+    ncurses
+    lcms2
+    librsync
+    openssl.dev
+  ] ++ lib.optionals stdenv.isDarwin [
+    Cocoa
+    Kernel
+    UniformTypeIdentifiers
+    UserNotifications
+    libpng
+    python3
+    zlib
+  ] ++ lib.optionals (stdenv.isDarwin && stdenv.isx86_64) [
+    Libsystem
+  ] ++ lib.optionals stdenv.isLinux [
+    fontconfig libunistring libcanberra libX11
+    libXrandr libXinerama libXcursor libxkbcommon libXi libXext
+    wayland-protocols wayland dbus libGL
+  ];
+
+  nativeBuildInputs = [
+    installShellFiles
+    ncurses
+    pkg-config
+    sphinx
+    furo
+    sphinx-copybutton
+    sphinxext-opengraph
+    sphinx-inline-tabs
+    go
+  ] ++ lib.optionals stdenv.isDarwin [
+    imagemagick
+    libicns  # For the png2icns tool.
+  ];
+
+  outputs = [ "out" "terminfo" "shell_integration" "kitten" ];
+
+  patches = [
+    # Gets `test_ssh_env_vars` to pass when `bzip2` is in the output of `env`.
+    ./fix-test_ssh_env_vars.patch
+
+    # Needed on darwin
+
+    # Gets `test_ssh_shell_integration` to pass for `zsh` when `compinit` complains about
+    # permissions.
+    ./zsh-compinit.patch
+
+    # Skip `test_ssh_bootstrap_with_different_launchers` when launcher is `zsh` since it causes:
+    # OSError: master_fd is in error condition
+    ./disable-test_ssh_bootstrap_with_different_launchers.patch
+
+    ./bold_is_bright.patch
+  ];
+
+  # Causes build failure due to warning
+  hardeningDisable = lib.optional stdenv.cc.isClang "strictoverflow";
+
+  CGO_ENABLED = 0;
+  GOFLAGS = "-trimpath";
+
+  go-modules = (buildGoModule {
+    pname = "kitty-go-modules";
+    inherit src vendorHash version;
+  }).go-modules;
+
+  configurePhase = ''
+    export GOCACHE=$TMPDIR/go-cache
+    export GOPATH="$TMPDIR/go"
+    export GOPROXY=off
+    cp -r --reflink=auto ${go-modules} vendor
+  '';
+
+  buildPhase = let
+    commonOptions = ''
+      --update-check-interval=0 \
+      --shell-integration=enabled\ no-rc
+    '';
+    darwinOptions = ''
+      --disable-link-time-optimization \
+      ${commonOptions}
+    '';
+  in ''
+    runHook preBuild
+    ${ lib.optionalString (stdenv.isDarwin && stdenv.isx86_64) "export MACOSX_DEPLOYMENT_TARGET=11" }
+    ${if stdenv.isDarwin then ''
+      ${python.pythonForBuild.interpreter} setup.py build ${darwinOptions}
+      make docs
+      ${python.pythonForBuild.interpreter} setup.py kitty.app ${darwinOptions}
+    '' else ''
+      ${python.pythonForBuild.interpreter} setup.py linux-package \
+      --egl-library='${lib.getLib libGL}/lib/libEGL.so.1' \
+      --startup-notification-library='${libstartup_notification}/lib/libstartup-notification-1.so' \
+      --canberra-library='${libcanberra}/lib/libcanberra.so' \
+      --fontconfig-library='${fontconfig.lib}/lib/libfontconfig.so' \
+      ${commonOptions}
+      ${python.pythonForBuild.interpreter} setup.py build-launcher
+    ''}
+    runHook postBuild
+  '';
+
+  nativeCheckInputs = [
+    pillow
+
+    # Shells needed for shell integration tests
+    bashInteractive
+    zsh
+    fish
+  ];
+
+  # skip failing tests due to darwin sandbox
+  preCheck = lib.optionalString stdenv.isDarwin ''
+    substituteInPlace kitty_tests/file_transmission.py \
+      --replace test_file_get dont_test_file_get \
+      --replace test_path_mapping_receive dont_test_path_mapping_receive
+    substituteInPlace kitty_tests/shell_integration.py \
+      --replace test_fish_integration dont_test_fish_integration
+    substituteInPlace kitty_tests/open_actions.py \
+      --replace test_parsing_of_open_actions dont_test_parsing_of_open_actions
+    substituteInPlace kitty_tests/ssh.py \
+      --replace test_ssh_connection_data dont_test_ssh_connection_data
+    substituteInPlace kitty_tests/fonts.py \
+      --replace 'class Rendering(BaseTest)' 'class Rendering'
+    # theme collection test starts an http server
+    rm tools/themes/collection_test.go
+  '';
+
+  checkPhase = ''
+      runHook preCheck
+
+      # Fontconfig error: Cannot load default config file: No such file: (null)
+      export FONTCONFIG_FILE=${fontconfig.out}/etc/fonts/fonts.conf
+
+      # Required for `test_ssh_shell_integration` to pass.
+      export TERM=kitty
+
+      make test
+      runHook postCheck
+    '';
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out
+    mkdir -p $kitten/bin
+    ${if stdenv.isDarwin then ''
+    mkdir "$out/bin"
+    ln -s ../Applications/kitty.app/Contents/MacOS/kitty "$out/bin/kitty"
+    ln -s ../Applications/kitty.app/Contents/MacOS/kitten "$out/bin/kitten"
+    cp ./kitty.app/Contents/MacOS/kitten "$kitten/bin/kitten"
+    mkdir "$out/Applications"
+    cp -r kitty.app "$out/Applications/kitty.app"
+
+    installManPage 'docs/_build/man/kitty.1'
+    '' else ''
+    cp -r linux-package/{bin,share,lib} $out
+    cp linux-package/bin/kitten $kitten/bin/kitten
+    ''}
+    wrapProgram "$out/bin/kitty" --prefix PATH : "$out/bin:${lib.makeBinPath [ imagemagick ncurses.dev ]}"
+
+    installShellCompletion --cmd kitty \
+      --bash <("$out/bin/kitty" +complete setup bash) \
+      --fish <("$out/bin/kitty" +complete setup fish2) \
+      --zsh  <("$out/bin/kitty" +complete setup zsh)
+
+    terminfo_src=${if stdenv.isDarwin then
+      ''"$out/Applications/kitty.app/Contents/Resources/terminfo"''
+      else
+      "$out/share/terminfo"}
+
+    mkdir -p $terminfo/share
+    mv "$terminfo_src" $terminfo/share/terminfo
+
+    mkdir -p $out/nix-support
+    echo "$terminfo" >> $out/nix-support/propagated-user-env-packages
+
+    cp -r 'shell-integration' "$shell_integration"
+
+    runHook postInstall
+  '';
+
+  passthru = {
+    updateScript = nix-update-script {};
+    tests.test = nixosTests.terminal-emulators.kitty;
+  };
+
+  meta = with lib; {
+    homepage = "https://github.com/kovidgoyal/kitty";
+    description = "A modern, hackable, featureful, OpenGL based terminal emulator";
+    license = licenses.gpl3Only;
+    changelog = "https://sw.kovidgoyal.net/kitty/changelog/";
+    platforms = platforms.darwin ++ platforms.linux;
+    maintainers = with maintainers; [ tex rvolosatovs Luflosi adamcstephens ];
+  };
+} //
+  (if stdenv.isDarwin then
+    { KITTY_NO_LTO = ""; }
+  else {
+    KITTY_EGL_LIBRARY = "${lib.getLib libGL}/lib/libEGL.so.1";
+    KITTY_STARTUP_NOTIFICATION_LIBRARY = "${libstartup_notification}/lib/libstartup-notification-1.so";
+    KITTY_CANBERRA_LIBRARY = "${libcanberra}/lib/libcanberra.so";
+  })

zsh-compinit.patch

@@ -0,0 +1,13 @@
+diff --git a/kitty_tests/ssh.py b/kitty_tests/ssh.py
+index 1f424146..d9a65d25 100644
+--- a/kitty_tests/ssh.py
++++ b/kitty_tests/ssh.py
+@@ -268,6 +268,8 @@ def check_untar_or_fail():
+                 return 'UNTAR_DONE' in q
+             pty.wait_till(check_untar_or_fail)
+             self.assertTrue(os.path.exists(os.path.join(home_dir, '.terminfo/kitty.terminfo')))
++            if login_shell == 'zsh':
++                pty.send_cmd_to_child('y')
+             if SHELL_INTEGRATION_VALUE != 'enabled':
+                 pty.wait_till(lambda: len(pty.screen_contents().splitlines()) > 1)
+                 self.assertEqual(pty.screen.cursor.shape, 0)